MASPC 1/MASPC_1.iso/Demos/Demo DIV/DATA/PRG/TUTOR/TUTOR0A.PRG

Text File | 1997-11-28 | 1.6 KB | 45 lines

//-----------------------------------------------------------------------
// TITULO: Tutorial 0
// AUTOR:  Daniel Navarro
// FECHA:  15/09/97
//-----------------------------------------------------------------------

PROGRAM Tutorial_0;
BEGIN
    load_fpg("tutorial\tutor0.fpg"); // Se carga el fichero de gráficos
    put_screen(0,2);  // Se pone el gráfico número 2 como fondo de pantalla
    nave();           // Se crea el proceso tipo "nave"
END

//-----------------------------------------------------------------------
// Maneja la nave protagonista
//-----------------------------------------------------------------------

PROCESS nave()
BEGIN
    graph=1; x=160; y=180;    // Selecciona el gráfico y las coordenadas
    LOOP                      // Entra en un bucle infinito
        x=mouse.x;            // Pone la nave en la coordenada x del ratón
        IF (mouse.left)       // Al pulsar el botón izquierdo del ratón se
            disparo(x,y-20);  // crea un proceso de tipo "disparo"
        END
        FRAME;                // Muestra la siguiente imagen de la nave
    END
END

//-----------------------------------------------------------------------
// Maneja los disparos de la nave protagonista
// Entradas: Coordenadas del gráfico
//-----------------------------------------------------------------------

PROCESS disparo(x,y)
BEGIN
    graph=3;    // Se selecciona el gráfico
    REPEAT      // Bucle de repetición
        y-=16;  // Se mueve hacia arriba 16 puntos
        FRAME;  // Muestra la siguiente imagen
    UNTIL (y<0) // Repite hasta que se salga por la parte superior
END